Post by CarlosQuiero importar desde una base de datos SQL Server a una base de datos
Access unas tablas, a través de código en un programa o formulario de
Visual Basic.
¿Como puedo hacer esto?
Hola, Carlos:
Prueba el siguiente ejemplo, el cual te creará una nueva tabla en una base
de datos Microsoft Access con los datos existentes en una base de SQL
Server:
Dim cnn As ADODB.Connection
Dim lNumRegAfect As Long
Dim strSQL As String
' Abrimos una conexión con la base de datos de Access
'
Set cnn = New ADODB.Connection
With cnn
.Provider = "Microsoft.Jet.OLEDB.4.0"
.ConnectionString = "Data Source=C:\Mis documentos\Bd1.mdb"
.Open
End With
' Construimos la consulta SQL, utilizando una cadena
' ODBC para conectarnos con SQL Server.
'
strSQL = "SELECT * INTO [Nueva Tabla Access] " & _
"FROM [Nombre Tabla de SQL Server] " & _
"IN ''[ODBC;Driver={SQL Server};" & _
"Server=Nombre servidor SQL Server;" & _
"Database=Nombre_Base_Datos_SQL_Server;" & _
"UID=cuenta_usuario;" & _
"PWD=contraseña_usuario]"
' Ejecutamos la consulta
cnn.Execute strSQL, lNumRegAfect, adExecuteNoRecords
' Leemos el número de registros que se han traspasado
MsgBox "Número de registros afectados: " & lNumRegAfect
' Cerramos la conexión
cnn.Close
Deberás de ejecutar el código tantas veces como tablas desees importar a la
base de Access.
Un saludo
--
Enrique Martínez
[MS MVP - VB]
Nota informativa: La información contenida en este mensaje, así como el
código fuente incluido en el mismo, se proporciona «COMO ESTÁ», sin
garantías de ninguna clase, y no otorga derecho alguno. Usted asume
cualquier riesgo al poner en práctica, utilizar o ejecutar lo recomendado o
sugerido en el presente mensaje.